-	script	gerenciar_cupom#mpago	-1,{
	OnAtcommand:
    if(getgroupid() != 99){dispbottom "Comando liberado somente para administradores"; end;}
    mes "Bem-vindo ao sistema de cupom!";
    mes "O que você gostaria de fazer?";
    next;
    switch(select("Criar Cupom:Editar Cupom:Excluir Cupom")) {
        case 1:
		mes "Por favor, insira as informações do cupom.";
		next;
		mes "Digite o código do cupom:";
		next;
		input .@cupom$;
		
		// Verificar se o cupom existe
		if(query_sql("SELECT id FROM rp_cupom WHERE cupom = '" + .@cupom$ + "'", .@cupom_id)) {
			mes "Cupom ja existe!, tente editar ou crie outro";
			close;
		}
		
		mes "Digite o nome do STREAMER:";
		next;
		input .@streamer$;
		
		mes "Digite o status do cupom (1 para ativo, 0 para inativo):";
		next;
		input .@status, 0, 1;
		
		mes "Digite a nova data e hora de validade do cupom no formato AAAA-MM-DD HH:MM:SS (exemplo: 2023-12-31 23:59:59):";
		next;
		input .@validade$;
		
		mes "Digite o percentual de desconto do cupom:";
		next;
		input .@percentual;
		
		// Inserir o cupom na tabela rp_cupom
		query_sql "INSERT INTO rp_cupom (streamer, cupom, status, criado, validade, percentual) VALUES ('" + .@streamer$ + "','" + .@cupom$ + "', " + .@status + ", NOW(), '" + .@validade$ + "', " + .@percentual + ")";
		
		mes "Cupom '"+.@cupom$+"' criado com sucesso!";
		close;
        case 2:
		mes "Digite o código do cupom que você deseja editar:";
		next;
		input .@cupom$;
		
		// Verificar se o cupom existe
		if(!query_sql("SELECT id FROM rp_cupom WHERE cupom = '" + .@cupom$ + "'", .@cupom_id)) {
			mes "Cupom não encontrado!";
			close;
		}
		
		mes "Digite o novo status do cupom (1 para ativo, 0 para inativo):";
		next;
		input .@status, 0, 1; // Input range between 0 and 1
		
		mes "Digite a nova data e hora de validade do cupom no formato AAAA-MM-DD HH:MM:SS (exemplo: 2023-12-31 23:59:59):";
		next;
		input .@validade$;
		
		mes "Digite o novo percentual de desconto do cupom:";
		next;
		input .@percentual;
		
		// Atualizar o cupom na tabela rp_cupom
		query_sql "UPDATE rp_cupom SET status = " + .@status + ", validade = '" + .@validade$ + "', percentual = " + .@percentual + " WHERE id = " + .@cupom_id;
		
		mes "Cupom atualizado com sucesso!";
		close;
        case 3:
		mes "Digite o código do cupom que você deseja excluir:";
		next;
		input .@cupom$;
		
		// Verificar se o cupom existe
		if(!query_sql("SELECT id FROM rp_cupom WHERE cupom = '" + .@cupom$ + "'", .@cupom_id)) {
			mes "Cupom não encontrado!";
			close;
		}
		
		// Confirmar a exclusão
		mes "Tem certeza de que deseja excluir o cupom '" + .@cupom$ + "'?";
		if(select("Sim:Não") == 2) {
			mes "Exclusão cancelada.";
			close;
		}
		
		// Excluir o cupom da tabela rp_cupom
		query_sql "DELETE FROM rp_cupom WHERE id = " + .@cupom_id;
		
		mes "Cupom excluído com sucesso!";
		close;
		break;
	}
	
	OnInit:
	bindatcmd "criarcupom",strnpcinfo(3)+"::OnAtcommand",99,0;
	end;
}